#! /bin/awk -f

# Guião awk para criação de utilizadores num servidor com LDAP/Samba e smbldap-tools
# S. Ramos 2/Set/2008 - adaptado de um guião da autoria de Pedro Fonseca
#
# Pode executar-se em modo teste, gerando apenas texto, usando a seguinte linha:
#
# ./gera_logins_turmas.awk < Estrutura_servidor.csv
#
# e executar-se definitivamente com:
#
# ./gera_logins_turmas.awk < Estrutura_servidor.csv | sh
#
# Recorre a um ficheiro csv com informação dos utilizadores e 
# grupos a que pertencem. Esse ficheiro tem uma linha por utilizador
# e as colunas contêm (separador=','):
# - nome utilizador
# - login
# - UID
# - Password
# - Grupo principal a que o utilizador pertence
# - Colunas com grupos adicionais
#


BEGIN { 
  FS=",";			# Separador de campos

   PrimeiroNome=1;		# Coluna onde está o nome por extenso
   Apelido=2;
   CampoLogin = 3;		# Coluna onde está o login
   UserID=4;
   ColunaPassword=5;
   gecos=6;
   PrimeiroCampocomGrupos=7;	# Primeira coluna com nomes de grupos
   UltimoCampoComGrupos=68;	# Ultima coluna com nomes de grupos
}

# Ciclo Principal
$0 !~/#/{			# Elimina linhas com '#'
  if($1!="Nome"){
    CriaUtilizador();
  }
  else{
    CriaEstrutura();		
  }
}


function CriaEstrutura()
{
  # Cria grupos

  for (n=PrimeiroCampocomGrupos;n<UltimoCampoComGrupos+1;n++){
    grupo[n] = tolower($n);
    linha_grupo = "smbldap-groupadd " grupo[n];
    print linha_grupo;
  }
}

# CriaUtilizador
#
function CriaUtilizador()
{
  if($1!="Nome"){
    
    linha_login = "smbldap-useradd -am ";
    linha_login = linha_login " -u " $UserID;
    linha_login = linha_login " -N " $PrimeiroNome;
    linha_login = linha_login " -S " $Apelido;
    linha_login = linha_login " -c " $gecos;
    
    Grupos=0;
    for ( atrib in grupo){
      if( ($atrib == "x") || ($atrib == "S"))
	Grupos = 1;
    }
    
    MaisGrupos = 0;
    if(Grupos){
      # Há grupos adicionais
      linha_login = linha_login " -G ";
      for (atrib in grupo){
	if(($atrib == "x") || ($atrib == "S")){
	  if(MaisGrupos)
	    linha_login = linha_login ",";
	  linha_login = linha_login grupo[atrib];
	  MaisGrupos=1;
	}
      }
    };
    
    linha_login = linha_login " " $CampoLogin;
    print linha_login;
    
    login = $CampoLogin;
    
    linha_pwd = "echo -e \""$ColunaPassword"\\n"$ColunaPassword"\" | smbldap-passwd --stdin " $CampoLogin ;
    print linha_pwd;
  }
}